root/arch/i386/kernel/entry.S

/* [previous][next][first][last][top][bottom][index][help] */ 
   1 /*
   2  *  linux/arch/i386/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  */
   6 
   7 /*
   8  * entry.S contains the system-call and fault low-level handling routines.
   9  * This also contains the timer-interrupt handler, as well as all interrupts
  10  * and faults that can result in a task-switch.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after a timer-interrupt and after each system call.
  14  *
  15  * I changed all the .align's to 4 (16 byte alignment), as that's faster
  16  * on a 486.
  17  *
  18  * Stack layout in 'ret_from_system_call':
  19  *      ptrace needs to have all regs on the stack.
  20  *      if the order here is changed, it needs to be 
  21  *      updated in fork.c:copy_process, signal.c:do_signal,
  22  *      ptrace.c and ptrace.h
  23  *
  24  *       0(%esp) - %ebx
  25  *       4(%esp) - %ecx
  26  *       8(%esp) - %edx
  27  *       C(%esp) - %esi
  28  *      10(%esp) - %edi
  29  *      14(%esp) - %ebp
  30  *      18(%esp) - %eax
  31  *      1C(%esp) - %ds
  32  *      20(%esp) - %es
  33  *      24(%esp) - %fs
  34  *      28(%esp) - %gs
  35  *      2C(%esp) - orig_eax
  36  *      30(%esp) - %eip
  37  *      34(%esp) - %cs
  38  *      38(%esp) - %eflags
  39  *      3C(%esp) - %oldesp
  40  *      40(%esp) - %oldss
  41  */
  42 
  43 #include <linux/sys.h>
  44 #include <linux/linkage.h>
  45 #include <asm/segment.h>
  46 #define ASSEMBLY
  47 #include <asm/smp.h>
  48 
  49 EBX             = 0x00
  50 ECX             = 0x04
  51 EDX             = 0x08
  52 ESI             = 0x0C
  53 EDI             = 0x10
  54 EBP             = 0x14
  55 EAX             = 0x18
  56 DS              = 0x1C
  57 ES              = 0x20
  58 FS              = 0x24
  59 GS              = 0x28
  60 ORIG_EAX        = 0x2C
  61 EIP             = 0x30
  62 CS              = 0x34
  63 EFLAGS          = 0x38
  64 OLDESP          = 0x3C
  65 OLDSS           = 0x40
  66 
  67 CF_MASK         = 0x00000001
  68 IF_MASK         = 0x00000200
  69 NT_MASK         = 0x00004000
  70 VM_MASK         = 0x00020000
  71 
  72 /*
  73  * these are offsets into the task-struct.
  74  */
  75 state           =  0
  76 counter         =  4
  77 priority        =  8
  78 signal          = 12
  79 blocked         = 16
  80 flags           = 20
  81 errno           = 24
  82 dbgreg6         = 52
  83 dbgreg7         = 56
  84 exec_domain     = 60
  85 
  86 ENOSYS = 38
  87 
  88 #define SAVE_ALL \
  89         cld; \
  90         push %gs; \
  91         push %fs; \
  92         push %es; \
  93         push %ds; \
  94         pushl %eax; \
  95         pushl %ebp; \
  96         pushl %edi; \
  97         pushl %esi; \
  98         pushl %edx; \
  99         pushl %ecx; \
 100         pushl %ebx; \
 101         movl $(KERNEL_DS),%edx; \
 102         mov %dx,%ds; \
 103         mov %dx,%es; \
 104         movl $(USER_DS),%edx; \
 105         mov %dx,%fs;
 106 
 107 #ifdef  __SMP__
 108 
 109 #define GET_PROCESSOR_ID \
 110         movl SYMBOL_NAME(apic_reg), %edx; \
 111         movl 32(%edx), %eax;\
 112         movl %eax,SYMBOL_NAME(apic_retval); \
 113         shrl $24,%eax; \
 114         andb $0x0F,%al;
 115 
 116 /*
 117  *      Get the processor ID multiplied by 4
 118  */
 119 
 120 #define GET_PROCESSOR_OFFSET(x) \
 121         movl SYMBOL_NAME(apic_reg), x ; \
 122         movl 32( x ), x ; \
 123         shrl $22, x ; \
 124         andl $0x3C, x ;
 125 
 126 /* macro LEAVE_KERNEL decrements kernel_counter and resets kernel_flag and
 127    saves processor variables if zero */
 128 #define LEAVE_KERNEL \
 129         pushfl; \
 130         cli; \
 131         decl SYMBOL_NAME(syscall_count); \
 132         decl SYMBOL_NAME(kernel_counter); \
 133         jnz 1f; \
 134         movb $(NO_PROC_ID), SYMBOL_NAME(active_kernel_processor); \
 135         lock; \
 136         btrl $0, SYMBOL_NAME(kernel_flag); \
 137 1:      popfl;
 138 
 139 /* macro ENTER_KERNEL waits for entering the kernel, increments
 140    kernel_counter, and reloads the processor variables if necessary
 141    uses : %eax, %edx (pushed and popped) 
 142 
 143    Note: We go to great pains to minimise the number of locked operations.
 144    We want to spin without locking, and lock when we attempt an update.
 145    The pentium has a MESI cache so the spin without lock will exit when
 146    another CPU write invalidates our cache, and the lock is avoided when
 147    possible so we don't play ping-pong games with the cache line.
 148 
 149 */
 150 
 151 #ifndef __SMP_PROF__
 152 
 153 #define SMP_PROF_A
 154 #define SMP_PROF_B 
 155 
 156 #else
 157 
 158 #define SMP_PROF_A movl $0,SYMBOL_NAME(smp_spins_syscall_cur)(,%eax,4);
 159 #define SMP_PROF_B incl SYMBOL_NAME(smp_spins_syscall)(,%eax,4); \
 160         incl SYMBOL_NAME(smp_spins_syscall_cur)(,%eax,4);
 161 #endif
 162 
 163 #define ENTER_KERNEL \
 164         pushl %eax; \
 165         pushl %edx; \
 166         pushfl; \
 167         cli; \
 168         GET_PROCESSOR_ID \
 169         SMP_PROF_A \
 170 1:      lock; \
 171         btsl $0, SYMBOL_NAME(kernel_flag); \
 172         jnc 3f; \
 173         cmpb SYMBOL_NAME(active_kernel_processor), %al; \
 174         je 4f; \
 175 2:      SMP_PROF_B \
 176         btl %al, SYMBOL_NAME(smp_invalidate_needed); \
 177         jnc 5f; \
 178         lock; \
 179         btrl %al, SYMBOL_NAME(smp_invalidate_needed); \
 180         jnc 5f; \
 181         movl %cr3,%edx; \
 182         movl %edx,%cr3; \
 183 5:      btl $0, SYMBOL_NAME(kernel_flag); \
 184         jc 2b; \
 185         jmp 1b; \
 186 3:      movb %al, SYMBOL_NAME(active_kernel_processor); \
 187 4:      incl SYMBOL_NAME(kernel_counter); \
 188         incl SYMBOL_NAME(syscall_count); \
 189         popfl; \
 190         popl %edx; \
 191         popl %eax;
 192 
 193 
 194 #define RESTORE_ALL \
 195         cmpw $(KERNEL_CS),CS(%esp); \
 196         je 1f;   \
 197         GET_PROCESSOR_OFFSET(%edx) \
 198         movl SYMBOL_NAME(current_set)(,%edx), %eax ; ; \
 199         movl dbgreg7(%eax),%ebx; \
 200         movl %ebx,%db7; \
 201 1:      LEAVE_KERNEL \
 202         popl %ebx; \
 203         popl %ecx; \
 204         popl %edx; \
 205         popl %esi; \
 206         popl %edi; \
 207         popl %ebp; \
 208         popl %eax; \
 209         pop %ds; \
 210         pop %es; \
 211         pop %fs; \
 212         pop %gs; \
 213         addl $4,%esp; \
 214         iret
 215 
 216 #else
 217 
 218 #define RESTORE_ALL \
 219         cmpw $(KERNEL_CS),CS(%esp); \
 220         je 1f;   \
 221         movl SYMBOL_NAME(current_set),%eax; \
 222         movl dbgreg7(%eax),%ebx; \
 223         movl %ebx,%db7; \
 224 1:      \
 225         popl %ebx; \
 226         popl %ecx; \
 227         popl %edx; \
 228         popl %esi; \
 229         popl %edi; \
 230         popl %ebp; \
 231         popl %eax; \
 232         pop %ds; \
 233         pop %es; \
 234         pop %fs; \
 235         pop %gs; \
 236         addl $4,%esp; \
 237         iret
 238 #endif
 239 
 240 
 241 ENTRY(lcall7)
 242         pushfl                  # We get a different stack layout with call gates,
 243         pushl %eax              # which has to be cleaned up later..
 244         SAVE_ALL
 245 #ifdef __SMP__
 246         ENTER_KERNEL
 247 #endif
 248         movl EIP(%esp),%eax     # due to call gates, this is eflags, not eip..
 249         movl CS(%esp),%edx      # this is eip..
 250         movl EFLAGS(%esp),%ecx  # and this is cs..
 251         movl %eax,EFLAGS(%esp)  #
 252         movl %edx,EIP(%esp)     # Now we move them to their "normal" places
 253         movl %ecx,CS(%esp)      #
 254         movl %esp,%eax
 255 #ifdef __SMP__
 256         GET_PROCESSOR_OFFSET(%edx)      # Processor offset into edx
 257         movl SYMBOL_NAME(current_set)(,%edx),%edx
 258 #else
 259         movl SYMBOL_NAME(current_set),%edx
 260 #endif
 261         pushl %eax
 262         movl exec_domain(%edx),%edx     # Get the execution domain
 263         movl 4(%edx),%edx       # Get the lcall7 handler for the domain
 264         call *%edx
 265         popl %eax
 266         jmp ret_from_sys_call
 267 
 268         ALIGN
 269 handle_bottom_half:
 270         pushfl
 271         incl SYMBOL_NAME(intr_count)
 272         sti
 273         call SYMBOL_NAME(do_bottom_half)
 274         popfl
 275         decl SYMBOL_NAME(intr_count)
 276         jmp 9f
 277         ALIGN
 278 reschedule:
 279         pushl $ret_from_sys_call
 280         jmp SYMBOL_NAME(schedule)    # test
 281 
 282 ENTRY(system_call)
 283         pushl %eax                      # save orig_eax
 284         SAVE_ALL
 285 #ifdef __SMP__
 286         ENTER_KERNEL
 287 #endif
 288         movl $-ENOSYS,EAX(%esp)
 289         cmpl $(NR_syscalls),%eax
 290         jae ret_from_sys_call
 291         movl SYMBOL_NAME(sys_call_table)(,%eax,4),%eax
 292         testl %eax,%eax
 293         je ret_from_sys_call
 294 #ifdef __SMP__
 295         GET_PROCESSOR_OFFSET(%edx)
 296         movl SYMBOL_NAME(current_set)(,%edx),%ebx
 297 #else
 298         movl SYMBOL_NAME(current_set),%ebx
 299 #endif
 300         andl $~CF_MASK,EFLAGS(%esp)     # clear carry - assume no errors
 301         movl $0,errno(%ebx)
 302         movl %db6,%edx
 303         movl %edx,dbgreg6(%ebx)  # save current hardware debugging status
 304         testb $0x20,flags(%ebx)         # PF_TRACESYS
 305         jne 1f
 306         call *%eax
 307         movl %eax,EAX(%esp)             # save the return value
 308         movl errno(%ebx),%edx
 309         negl %edx
 310         je ret_from_sys_call
 311         movl %edx,EAX(%esp)
 312         orl $(CF_MASK),EFLAGS(%esp)     # set carry to indicate error
 313         jmp ret_from_sys_call
 314         ALIGN
 315 1:      call SYMBOL_NAME(syscall_trace)
 316         movl ORIG_EAX(%esp),%eax
 317         call SYMBOL_NAME(sys_call_table)(,%eax,4)
 318         movl %eax,EAX(%esp)             # save the return value
 319 #ifdef __SMP__
 320         GET_PROCESSOR_OFFSET(%eax)
 321         movl SYMBOL_NAME(current_set)(,%eax),%eax
 322 #else
 323         movl SYMBOL_NAME(current_set),%eax
 324 #endif
 325         movl errno(%eax),%edx
 326         negl %edx
 327         je 1f
 328         movl %edx,EAX(%esp)
 329         orl $(CF_MASK),EFLAGS(%esp)     # set carry to indicate error
 330 1:      call SYMBOL_NAME(syscall_trace)
 331 
 332         ALIGN
 333         .globl ret_from_sys_call
 334 ret_from_sys_call:
 335         cmpl $0,SYMBOL_NAME(intr_count)
 336         jne 2f
 337 9:      movl SYMBOL_NAME(bh_mask),%eax
 338         andl SYMBOL_NAME(bh_active),%eax
 339         jne handle_bottom_half
 340         movl EFLAGS(%esp),%eax          # check VM86 flag: CS/SS are
 341         testl $(VM_MASK),%eax           # different then
 342         jne 1f
 343         cmpw $(KERNEL_CS),CS(%esp)      # was old code segment supervisor ?
 344         je 2f
 345 1:      sti
 346         orl $(IF_MASK),%eax             # these just try to make sure
 347         andl $~NT_MASK,%eax             # the program doesn't do anything
 348         movl %eax,EFLAGS(%esp)          # stupid
 349         cmpl $0,SYMBOL_NAME(need_resched)
 350         jne reschedule
 351 #ifdef __SMP__
 352         GET_PROCESSOR_OFFSET(%eax)
 353         movl SYMBOL_NAME(current_set)(,%eax), %eax
 354 #else
 355         movl SYMBOL_NAME(current_set),%eax
 356 #endif
 357         cmpl SYMBOL_NAME(task),%eax     # task[0] cannot have signals
 358         je 2f
 359         movl blocked(%eax),%ecx
 360         movl %ecx,%ebx                  # save blocked in %ebx for signal handling
 361         notl %ecx
 362         andl signal(%eax),%ecx
 363         jne signal_return
 364 2:      RESTORE_ALL
 365         ALIGN
 366 signal_return:
 367         movl %esp,%ecx
 368         pushl %ecx
 369         testl $(VM_MASK),EFLAGS(%ecx)
 370         jne v86_signal_return
 371         pushl %ebx
 372         call SYMBOL_NAME(do_signal)
 373         popl %ebx
 374         popl %ebx
 375         RESTORE_ALL
 376         ALIGN
 377 v86_signal_return:
 378         call SYMBOL_NAME(save_v86_state)
 379         movl %eax,%esp
 380         pushl %eax
 381         pushl %ebx
 382         call SYMBOL_NAME(do_signal)
 383         popl %ebx
 384         popl %ebx
 385         RESTORE_ALL
 386 
 387 ENTRY(divide_error)
 388         pushl $0                # no error code
 389         pushl $ SYMBOL_NAME(do_divide_error)
 390         ALIGN
 391 error_code:
 392         push %fs
 393         push %es
 394         push %ds
 395         pushl %eax
 396         pushl %ebp
 397         pushl %edi
 398         pushl %esi
 399         pushl %edx
 400         pushl %ecx
 401         pushl %ebx
 402         movl $0,%eax
 403         movl %eax,%db7                  # disable hardware debugging...
 404         cld
 405         movl $-1, %eax
 406         xchgl %eax, ORIG_EAX(%esp)      # orig_eax (get the error code. )
 407         xorl %ebx,%ebx                  # zero ebx
 408         mov %gs,%bx                     # get the lower order bits of gs
 409         xchgl %ebx, GS(%esp)            # get the address and save gs.
 410         pushl %eax                      # push the error code
 411         lea 4(%esp),%edx
 412         pushl %edx
 413         movl $(KERNEL_DS),%edx
 414         mov %dx,%ds
 415         mov %dx,%es
 416         movl $(USER_DS),%edx
 417         mov %dx,%fs
 418 #ifdef __SMP__
 419         ENTER_KERNEL
 420 #endif
 421         pushl %eax
 422 #ifdef __SMP__
 423         GET_PROCESSOR_OFFSET(%eax)
 424         movl SYMBOL_NAME(current_set)(,%eax), %eax
 425 #else
 426         movl SYMBOL_NAME(current_set),%eax
 427 #endif
 428         movl %db6,%edx
 429         movl %edx,dbgreg6(%eax)  # save current hardware debugging status
 430         popl %eax
 431         call *%ebx
 432         addl $8,%esp
 433         jmp ret_from_sys_call
 434 
 435 ENTRY(coprocessor_error)
 436         pushl $0
 437         pushl $ SYMBOL_NAME(do_coprocessor_error)
 438         jmp error_code
 439 
 440 ENTRY(device_not_available)
 441         pushl $-1               # mark this as an int
 442         SAVE_ALL
 443 #ifdef __SMP__
 444         ENTER_KERNEL
 445 #endif
 446         pushl $ret_from_sys_call
 447         movl %cr0,%eax
 448         testl $0x4,%eax                 # EM (math emulation bit)
 449         je SYMBOL_NAME(math_state_restore)
 450         pushl $0                # temporary storage for ORIG_EIP
 451         call  SYMBOL_NAME(math_emulate)
 452         addl $4,%esp
 453         ret
 454 
 455 ENTRY(debug)
 456         pushl $0
 457         pushl $ SYMBOL_NAME(do_debug)
 458         jmp error_code
 459 
 460 ENTRY(nmi)
 461         pushl $0
 462         pushl $ SYMBOL_NAME(do_nmi)
 463         jmp error_code
 464 
 465 ENTRY(int3)
 466         pushl $0
 467         pushl $ SYMBOL_NAME(do_int3)
 468         jmp error_code
 469 
 470 ENTRY(overflow)
 471         pushl $0
 472         pushl $ SYMBOL_NAME(do_overflow)
 473         jmp error_code
 474 
 475 ENTRY(bounds)
 476         pushl $0
 477         pushl $ SYMBOL_NAME(do_bounds)
 478         jmp error_code
 479 
 480 ENTRY(invalid_op)
 481         pushl $0
 482         pushl $ SYMBOL_NAME(do_invalid_op)
 483         jmp error_code
 484 
 485 ENTRY(coprocessor_segment_overrun)
 486         pushl $0
 487         pushl $ SYMBOL_NAME(do_coprocessor_segment_overrun)
 488         jmp error_code
 489 
 490 ENTRY(reserved)
 491         pushl $0
 492         pushl $ SYMBOL_NAME(do_reserved)
 493         jmp error_code
 494 
 495 ENTRY(double_fault)
 496         pushl $ SYMBOL_NAME(do_double_fault)
 497         jmp error_code
 498 
 499 ENTRY(invalid_TSS)
 500         pushl $ SYMBOL_NAME(do_invalid_TSS)
 501         jmp error_code
 502 
 503 ENTRY(segment_not_present)
 504         pushl $ SYMBOL_NAME(do_segment_not_present)
 505         jmp error_code
 506 
 507 ENTRY(stack_segment)
 508         pushl $ SYMBOL_NAME(do_stack_segment)
 509         jmp error_code
 510 
 511 ENTRY(general_protection)
 512         pushl $ SYMBOL_NAME(do_general_protection)
 513         jmp error_code
 514 
 515 ENTRY(alignment_check)
 516         pushl $ SYMBOL_NAME(do_alignment_check)
 517         jmp error_code
 518 
 519 ENTRY(page_fault)
 520         pushl $ SYMBOL_NAME(do_page_fault)
 521         jmp error_code
 522 
 523 .data
 524 ENTRY(sys_call_table)
 525         .long SYMBOL_NAME(sys_setup)            /* 0 */
 526         .long SYMBOL_NAME(sys_exit)
 527         .long SYMBOL_NAME(sys_fork)
 528         .long SYMBOL_NAME(sys_read)
 529         .long SYMBOL_NAME(sys_write)
 530         .long SYMBOL_NAME(sys_open)             /* 5 */
 531         .long SYMBOL_NAME(sys_close)
 532         .long SYMBOL_NAME(sys_waitpid)
 533         .long SYMBOL_NAME(sys_creat)
 534         .long SYMBOL_NAME(sys_link)
 535         .long SYMBOL_NAME(sys_unlink)           /* 10 */
 536         .long SYMBOL_NAME(sys_execve)
 537         .long SYMBOL_NAME(sys_chdir)
 538         .long SYMBOL_NAME(sys_time)
 539         .long SYMBOL_NAME(sys_mknod)
 540         .long SYMBOL_NAME(sys_chmod)            /* 15 */
 541         .long SYMBOL_NAME(sys_chown)
 542         .long SYMBOL_NAME(sys_break)
 543         .long SYMBOL_NAME(sys_stat)
 544         .long SYMBOL_NAME(sys_lseek)
 545         .long SYMBOL_NAME(sys_getpid)           /* 20 */
 546         .long SYMBOL_NAME(sys_mount)
 547         .long SYMBOL_NAME(sys_umount)
 548         .long SYMBOL_NAME(sys_setuid)
 549         .long SYMBOL_NAME(sys_getuid)
 550         .long SYMBOL_NAME(sys_stime)            /* 25 */
 551         .long SYMBOL_NAME(sys_ptrace)
 552         .long SYMBOL_NAME(sys_alarm)
 553         .long SYMBOL_NAME(sys_fstat)
 554         .long SYMBOL_NAME(sys_pause)
 555         .long SYMBOL_NAME(sys_utime)            /* 30 */
 556         .long SYMBOL_NAME(sys_stty)
 557         .long SYMBOL_NAME(sys_gtty)
 558         .long SYMBOL_NAME(sys_access)
 559         .long SYMBOL_NAME(sys_nice)
 560         .long SYMBOL_NAME(sys_ftime)            /* 35 */
 561         .long SYMBOL_NAME(sys_sync)
 562         .long SYMBOL_NAME(sys_kill)
 563         .long SYMBOL_NAME(sys_rename)
 564         .long SYMBOL_NAME(sys_mkdir)
 565         .long SYMBOL_NAME(sys_rmdir)            /* 40 */
 566         .long SYMBOL_NAME(sys_dup)
 567         .long SYMBOL_NAME(sys_pipe)
 568         .long SYMBOL_NAME(sys_times)
 569         .long SYMBOL_NAME(sys_prof)
 570         .long SYMBOL_NAME(sys_brk)              /* 45 */
 571         .long SYMBOL_NAME(sys_setgid)
 572         .long SYMBOL_NAME(sys_getgid)
 573         .long SYMBOL_NAME(sys_signal)
 574         .long SYMBOL_NAME(sys_geteuid)
 575         .long SYMBOL_NAME(sys_getegid)          /* 50 */
 576         .long SYMBOL_NAME(sys_acct)
 577         .long SYMBOL_NAME(sys_phys)
 578         .long SYMBOL_NAME(sys_lock)
 579         .long SYMBOL_NAME(sys_ioctl)
 580         .long SYMBOL_NAME(sys_fcntl)            /* 55 */
 581         .long SYMBOL_NAME(sys_mpx)
 582         .long SYMBOL_NAME(sys_setpgid)
 583         .long SYMBOL_NAME(sys_ulimit)
 584         .long SYMBOL_NAME(sys_olduname)
 585         .long SYMBOL_NAME(sys_umask)            /* 60 */
 586         .long SYMBOL_NAME(sys_chroot)
 587         .long SYMBOL_NAME(sys_ustat)
 588         .long SYMBOL_NAME(sys_dup2)
 589         .long SYMBOL_NAME(sys_getppid)
 590         .long SYMBOL_NAME(sys_getpgrp)          /* 65 */
 591         .long SYMBOL_NAME(sys_setsid)
 592         .long SYMBOL_NAME(sys_sigaction)
 593         .long SYMBOL_NAME(sys_sgetmask)
 594         .long SYMBOL_NAME(sys_ssetmask)
 595         .long SYMBOL_NAME(sys_setreuid)         /* 70 */
 596         .long SYMBOL_NAME(sys_setregid)
 597         .long SYMBOL_NAME(sys_sigsuspend)
 598         .long SYMBOL_NAME(sys_sigpending)
 599         .long SYMBOL_NAME(sys_sethostname)
 600         .long SYMBOL_NAME(sys_setrlimit)        /* 75 */
 601         .long SYMBOL_NAME(sys_getrlimit)
 602         .long SYMBOL_NAME(sys_getrusage)
 603         .long SYMBOL_NAME(sys_gettimeofday)
 604         .long SYMBOL_NAME(sys_settimeofday)
 605         .long SYMBOL_NAME(sys_getgroups)        /* 80 */
 606         .long SYMBOL_NAME(sys_setgroups)
 607         .long SYMBOL_NAME(old_select)
 608         .long SYMBOL_NAME(sys_symlink)
 609         .long SYMBOL_NAME(sys_lstat)
 610         .long SYMBOL_NAME(sys_readlink)         /* 85 */
 611         .long SYMBOL_NAME(sys_uselib)
 612         .long SYMBOL_NAME(sys_swapon)
 613         .long SYMBOL_NAME(sys_reboot)
 614         .long SYMBOL_NAME(old_readdir)
 615         .long SYMBOL_NAME(old_mmap)             /* 90 */
 616         .long SYMBOL_NAME(sys_munmap)
 617         .long SYMBOL_NAME(sys_truncate)
 618         .long SYMBOL_NAME(sys_ftruncate)
 619         .long SYMBOL_NAME(sys_fchmod)
 620         .long SYMBOL_NAME(sys_fchown)           /* 95 */
 621         .long SYMBOL_NAME(sys_getpriority)
 622         .long SYMBOL_NAME(sys_setpriority)
 623         .long SYMBOL_NAME(sys_profil)
 624         .long SYMBOL_NAME(sys_statfs)
 625         .long SYMBOL_NAME(sys_fstatfs)          /* 100 */
 626         .long SYMBOL_NAME(sys_ioperm)
 627         .long SYMBOL_NAME(sys_socketcall)
 628         .long SYMBOL_NAME(sys_syslog)
 629         .long SYMBOL_NAME(sys_setitimer)
 630         .long SYMBOL_NAME(sys_getitimer)        /* 105 */
 631         .long SYMBOL_NAME(sys_newstat)
 632         .long SYMBOL_NAME(sys_newlstat)
 633         .long SYMBOL_NAME(sys_newfstat)
 634         .long SYMBOL_NAME(sys_uname)
 635         .long SYMBOL_NAME(sys_iopl)             /* 110 */
 636         .long SYMBOL_NAME(sys_vhangup)
 637         .long SYMBOL_NAME(sys_idle)
 638         .long SYMBOL_NAME(sys_vm86)
 639         .long SYMBOL_NAME(sys_wait4)
 640         .long SYMBOL_NAME(sys_swapoff)          /* 115 */
 641         .long SYMBOL_NAME(sys_sysinfo)
 642         .long SYMBOL_NAME(sys_ipc)
 643         .long SYMBOL_NAME(sys_fsync)
 644         .long SYMBOL_NAME(sys_sigreturn)
 645         .long SYMBOL_NAME(sys_clone)            /* 120 */
 646         .long SYMBOL_NAME(sys_setdomainname)
 647         .long SYMBOL_NAME(sys_newuname)
 648         .long SYMBOL_NAME(sys_modify_ldt)
 649         .long SYMBOL_NAME(sys_adjtimex)
 650         .long SYMBOL_NAME(sys_mprotect)         /* 125 */
 651         .long SYMBOL_NAME(sys_sigprocmask)
 652         .long SYMBOL_NAME(sys_create_module)
 653         .long SYMBOL_NAME(sys_init_module)
 654         .long SYMBOL_NAME(sys_delete_module)
 655         .long SYMBOL_NAME(sys_get_kernel_syms)  /* 130 */
 656         .long SYMBOL_NAME(sys_quotactl)
 657         .long SYMBOL_NAME(sys_getpgid)
 658         .long SYMBOL_NAME(sys_fchdir)
 659         .long SYMBOL_NAME(sys_bdflush)
 660         .long SYMBOL_NAME(sys_sysfs)            /* 135 */
 661         .long SYMBOL_NAME(sys_personality)
 662         .long 0                                 /* for afs_syscall */
 663         .long SYMBOL_NAME(sys_setfsuid)
 664         .long SYMBOL_NAME(sys_setfsgid)
 665         .long SYMBOL_NAME(sys_llseek)           /* 140 */
 666         .long SYMBOL_NAME(sys_getdents)
 667         .long SYMBOL_NAME(sys_select)
 668         .long SYMBOL_NAME(sys_flock)
 669         .long SYMBOL_NAME(sys_msync)
 670         .long SYMBOL_NAME(sys_readv)            /* 145 */
 671         .long SYMBOL_NAME(sys_writev)
 672         .long SYMBOL_NAME(sys_getsid)
 673         .long SYMBOL_NAME(sys_fdatasync)
 674         .long SYMBOL_NAME(sys_sysctl)
 675         .long SYMBOL_NAME(sys_mlock)            /* 150 */
 676         .long SYMBOL_NAME(sys_munlock)
 677         .long SYMBOL_NAME(sys_mlockall)
 678         .long SYMBOL_NAME(sys_munlockall)
 679         .long SYMBOL_NAME(sys_sched_setparam)
 680         .long SYMBOL_NAME(sys_sched_getparam)   /* 155 */
 681         .long SYMBOL_NAME(sys_sched_setscheduler)
 682         .long SYMBOL_NAME(sys_sched_getscheduler)
 683         .long SYMBOL_NAME(sys_sched_yield)
 684         .long SYMBOL_NAME(sys_sched_get_priority_max)
 685         .long SYMBOL_NAME(sys_sched_get_priority_min)  /* 160 */
 686         .long SYMBOL_NAME(sys_sched_rr_get_interval)
 687         .long SYMBOL_NAME(sys_nanosleep)
 688         .space (NR_syscalls-163)*4
/* [previous][next][first][last][top][bottom][index][help] */